#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"


camera {  location <7,4,6>   look_at <0.1,0.5,0.25>  }

light_source { <-5,20,5> color White }  
light_source { <10,2,10> color White }  
light_source { <-5,0,-5> color White }  




#declare Tail = difference {
  union {
    box { <2,0.25,0.375>, <-2,-0.25,-0.375> rotate z*15 }
    box { <2,0.25,0.375>, <-2,-0.25,-0.375> rotate z*(-15) }
  }
  box { <0.75,-2,0.375+0.1>, <3,2,-0.375-0.1> }
  box { <0,-2,0.375+0.1>, <-3,2,-0.375-0.1> }
}

#declare Tail_side = union {
  box { <2,2,0.375>, <-2,-2,-0.375> }
  object {Tail translate y*0.75 translate x*2}
  object {Tail translate -y*0.75 translate x*2}
  object {Tail rotate z*180 translate y*0.75 translate x*(-2)}
  object {Tail rotate z*180 translate -y*0.75 translate x*(-2)}
  bounded_by {box { <2.75,2,0.375>, <-2.75,-2,-0.375> }}
}

#declare Other_side = difference {
  box { <2.75,2,0.375>, <-2.75,-2,-0.375> }
  object { Tail_side 
      translate x*-2.375 
      scale <1.01,1.01,1.01> 
      rotate y*-90 
      translate x*2.375
  }
  object { Tail_side 
      translate x*2.375 
      scale <1.01,1.01,1.01> 
      rotate y*90 
      translate x*-2.375
  }
  bounded_by { box { <2.75,2,0.375>, <-2.75,-2,-0.375> } }
}


#declare The_wood1 = 
 pigment 
  {wood
   turbulence 0.05
   color_map 
    {[0.0, 0.8  color red 0.666 green 0.45 blue 0.225
                color red 0.666 green 0.45 blue 0.225]
     [0.8, 1.01 color red 0.45   green 0.3   blue 0.175
                color red 0.3   green 0.225   blue 0.175]
    }
  }
#declare The_wood2 = 
 pigment 
  {wood
   turbulence 0.05
   color_map 
    {[0.0, 0.8  color red 0.888 green 0.600 blue 0.3
                color red 0.888 green 0.600 blue 0.3]
     [0.8, 1.01 color red 0.6   green 0.4   blue 0.2
                color red 0.4   green 0.3   blue 0.2]
    }
  }


object {
  Tail_side 
  translate x*3.249
  rotate y*90
  pigment {
    The_wood1
    scale 0.45*0.25
  }
  rotate y*-90
  translate x*-3.249
  translate z*2.375
}
object {
  Tail_side 
  translate x*5.23
  rotate y*90
  pigment {
    The_wood1
    scale 0.39*0.25
  }
  rotate y*-90
  translate x*-5.23
  translate z*-2.375
}

object {
  Other_side 
  translate y*9.45
  rotate y*90
  pigment {
    The_wood2
    scale 0.48*0.25
  }
  rotate y*-90
  translate y*-9.45
  rotate y*90 
  translate x*2.375
}
object {
  Other_side 
  translate y*4.42
  rotate y*90
  pigment {
    The_wood2
    scale 0.35*0.25
  }
  rotate y*-90
  translate y*-4.42
  rotate y*-90 
  translate x*-2.375
}