#include "colors.inc"
#include "chars.inc"
#include "textures.inc"

#declare postwidth= 0.25

#declare LIGHT1=1   // white area
#declare LIGHT2=1   // blue area
#declare LIGHT3=1    // spotlight
//#declare STANDBACK=1

camera {
#ifdef (STANDBACK)
  location <2,0.25,8> look_at <-1,2,1>
#else
  location <2,2,3> look_at <0,0,0>
#end
}




#ifdef (STANDBACK)
union {
  box { <1,0.75,0.25>, <-1,-0.75,-0.25> }
  cylinder { <0,0,0>, <0,0,1.1> 0.6 }
  texture {
    pigment {color White}
    finish {ambient 0.5}
  }
  scale 0.25
  rotate z*180
  rotate x*61
  rotate x*90
  rotate y*-56.3
  rotate y*90
  translate <2,2,3>
}

box { 
  <0,0,0.01>, <1,1,-0.01>
  texture {
    pigment {
      image_map {tga "xyz_zoom.tga" once}
    }
    finish { ambient 1.0 }
  }
  scale <2,1.5,1>
  translate <-1,-0.75,0>
  scale 0.661
  translate z*1.0
  rotate z*180
  rotate x*61
  rotate x*90
  rotate y*-56.3
  rotate y*90
  translate <2,2,3>
  //no_shadow
}
#end


#ifdef (LIGHT1)
light_source { 
  <0,2,6> 
  color White 
  looks_like { 
    sphere {
      <0,0,0>,0.1 
      texture {
        pigment {color White}
        finish {ambient 1}
      } 
    }
  }
}
#end

#ifdef (LIGHT2)
light_source { 
  <-6,6,0> 
  color Blue 
  looks_like { 
    sphere {
      <0,0,0>,0.1 
      texture {
        pigment {color Blue}
        finish {ambient 1}
      } 
    }
  }
}
#end

#ifdef (LIGHT3)
light_source {
  <0, 6, 0>
  color White
  spotlight
  radius 15
  falloff 40
  tightness 10
  point_at <0, 0, 0>
  looks_like {
    cone {
      <0,0,0>,0.25, <0,0.3,0>,0.05
      texture {
        pigment {color White}
        finish {ambient 1}
      }
    }
  }
  translate <(-postwidth+1.125+postwidth)/2,0,(-postwidth+1.125+postwidth)/2>
}
#end




plane { <0,1,0>, -1 pigment { color White } }


#declare Arrow = union {  // along X axis
  cylinder { <-0.5,0,0>, <0.3,0,0>, 0.01 }
  cone { <0.5,0,0>,0, <0.3,0,0>, 0.05 }
  difference {
    cone { <-0.5,0,0>,0.075, <-0.4,0,0>, 0 }
    union { 
      box { <-0.51,0.25,0.01> <-0.4,-0.25,0.1> }
      box { <-0.51,0.25,-0.01> <-0.4,-0.25,-0.1> }
    }
  }
  difference {
    cone { <-0.5,0,0>,0.075, <-0.4,0,0>, 0 }
    union { 
      box { <-0.51,0.25,0.01> <-0.4,-0.25,0.1> }
      box { <-0.51,0.25,-0.01> <-0.4,-0.25,-0.1> }
      rotate x*90
    }
  }
}

// X arrow
union {
  object { Arrow }
  object { char_X translate y*-2.5 scale 0.1 rotate y*90 }
  pigment { color Red }
  translate x*0.625
}

// Y arrow
union {
  object { Arrow }
  object { char_Y translate y*-2.5 scale 0.1 rotate y*90 }
  pigment { color Green }
  translate x*0.625
  rotate z*90
}

// Z arrow
union {
  object { Arrow }
  object { char_Z translate y*-2.5 scale 0.1 rotate y*90 }
  pigment { color Blue }
  translate x*0.625
  rotate y*-90
}


#declare post= box {
  <-postwidth/2,-1,-postwidth/2>,<postwidth/2,1.125,postwidth/2>
}

union {
  object { post translate <     -postwidth/2,0,-postwidth/2> }
  object { post translate <1.125+postwidth/2,0,-postwidth/2> }
  object { post translate <     -postwidth/2,0,1.125+postwidth/2> }
  object { post translate <1.125+postwidth/2,0,1.125+postwidth/2> }
  
  box {
    <-postwidth,1.125,-postwidth>,
        <1.125+postwidth,1.125+postwidth,1.125+postwidth>
  }

  texture { 
    Glass2 
    //finish { caustics 2.0 }
  }
  //pigment { color White }
}